久久精品官网,欧美综合77777色婷婷,久久久久在线

asp日歷代碼

深山行者個人網站 2009/12/22 14:07:45 深山行者字體:大中小瀏覽 14378

演示效果

以下為詳細代碼

<html> 
<head> 
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" /> 
<link  rel="schema.DC" /> 
<title>asp日歷代碼</title 
></head> 
<body bgcolor="#FFFFFF"> 
<% 
' 要調用的函數聲明 
'根據年份及月份得到每月的總天數 
Function GetDaysInMonth(iMonth, iYear) 
Select Case iMonth 
Case 1, 3, 5, 7, 8, 10, 12 
GetDaysInMonth = 31 
Case 4, 6, 9, 11 
GetDaysInMonth = 30 
Case 2 
If IsDate("February 29, " & iYear) Then 
GetDaysInMonth = 29 
Else 
GetDaysInMonth = 28 
End If 
End Select 
End Function 
'得到一個月開始的日期. 
Function GetWeekdayMonthStartsOn(dAnyDayInTheMonth) 
Dim dTemp 
dTemp = DateAdd("d", -(Day(dAnyDayInTheMonth) - 1), dAnyDayInTheMonth) 
GetWeekdayMonthStartsOn = WeekDay(dTemp) 
End Function 
'得到當前一個月的上一個月. 
Function SubtractOneMonth(dDate) 
SubtractOneMonth = DateAdd("m", -1, dDate) 
End Function 
'得到當前一個月的下一個月. 
Function AddOneMonth(dDate) 
AddOneMonth = DateAdd("m", 1, dDate) 
End Function 
' 函數聲明結束

Dim dDate ' 日歷顯示的日期 
Dim iDOW ' 每一月開始的日期 
Dim iCurrent ' 當前日期 
Dim iPosition ' 表格中的當前位置

' 得到選擇的日期并檢查日期的合法性 
If IsDate(Request.QueryString("date")) Then 
dDate = CDate(Request.QueryString("date")) 
Else 
If IsDate(Request.QueryString("month") & "-" & Request.QueryString("day") & "-" & Request.QueryString("year")) Then 
dDate = CDate(Request.QueryString("month") & "-" & Request.QueryString("day") & "-" & Request.QueryString("year")) 
Else 
dDate = Date()

If Len(Request.QueryString("month")) <> 0 Or Len(Request.QueryString("day")) <> 0 Or Len(Request.QueryString("year")) <> 0 Or Len(Request.QueryString("date")) <> 0 Then 
Response.Write "您所選擇的日期格式不正確，系統會使用當前日期.<BR><BR>" 
End If

End If 
End If

'得到日期后我們先得到這個月的天數及這個月的起始日期. 
iDIM = GetDaysInMonth(Month(dDate), Year(dDate)) 
iDOW = GetWeekdayMonthStartsOn(dDate)

%> 
<table width="180" height="100%" border="0" cellpadding="0" cellspacing="0"> 
<tr> 
<td><table width="150" border="0" align="center" cellpadding="0" cellspacing="0"> 
<tr> 
<td height="5"> </td> 
</tr> 
</table> 
<table width="180" border="0" align="center" cellpadding="0" cellspacing="0"> 
<tr> 
<td align="center" colspan="7"><table border="0" cellpadding="0" cellspacing="0"width="100%"> 
<tr> 
<td height="22" align="right"><a href="rl.asp?date=<%= SubtractOneMonth(dDate) %>"><img src="../images/dot_left.gif" width="15" height="14" border="0" /></a></td> 
<td align="center"><font color="999999"><b><%= MonthName(Month(dDate)) & " " & Year(dDate) %></b></font></td> 
<td><a href="rl.asp?date=<%= AddOneMonth(dDate) %>"><img src="../images/dot_right.gif" width="15" height="14" border="0" /></a></td> 
</tr> 
</table></td> 
</tr> 
<tr> 
<td width="25" height="22" align="center"><font 
color="d08c00"><b>日</b></font> </td> 
<td width="25" align="center"><b><font color="999999">一</font></b> </td> 
<td width="25" align="center"><b><font color="999999">二</font></b> </td> 
<td width="25" align="center"><b><font color="999999">三</font></b> </td> 
<td width="25" align="center"><b><font color="999999">四</font></b> </td> 
<td width="25" align="center"><b><font color="999999">五</font></b> </td> 
<td width="25" align="center"><b><font color="d08c00">六</font></b> </td> 
</tr> 
<% 
' 如果這個月的起始日期不是周日的話就加空的單元. 
If iDOW <> 1 Then 
Response.Write vbTab & "<TR>" & vbCrLf 
iPosition = 1 
Do While iPosition < iDOW 
Response.Write vbTab & vbTab & "<TD> </TD>" & vbCrLf 
iPosition = iPosition + 1 
Loop 
End If

' 繪制這個月的日歷 
iCurrent = 1 
iPosition = iDOW 
Do While iCurrent <= iDIM 
' 如果是一行的開頭就使用 TR 標記 
If iPosition = 1 Then 
Response.Write vbTab & "<TR>" & vbCrLf 
End If

' 如果這一天是我們選擇的日期就高亮度顯示該日期. 
If iCurrent = Day(dDate) Then 
Response.Write vbTab & vbTab & "<TD BGCOLOR=#eeeeee height=18 align=center><B>" & iCurrent & "</B></TD>" & vbCrLf 
Else 
Response.Write vbTab & vbTab & "<TD height=18 align=center><A HREF=""./rl.asp?date=" & Month(dDate) & "-" & iCurrent & "-" & Year(dDate) & """>" & iCurrent & "</A></TD>" & vbCrLf 
End If

' 如果滿一周的話表格就另起一行 
If iPosition = 7 Then 
Response.Write vbTab & "</TR>" & vbCrLf 
iPosition = 0 
End If

iCurrent = iCurrent + 1 
iPosition = iPosition + 1 
Loop

' 如果一個月不是以周六結束則加上相應的空單元. 
If iPosition <> 1 Then 
Do While iPosition <= 7 
Response.Write vbTab & vbTab & "<TD> </TD>" & vbCrLf 
iPosition = iPosition + 1 
Loop 
Response.Write vbTab & "</TR>" & vbCrLf 
End If 
%> 
</table> 
<table width="150" border="0" align="center" cellpadding="0" cellspacing="0"> 
<tr> 
<td height="5"> </td> 
</tr> 
</table></td> 
</tr> 
</table>

前一頁:ASP漢字轉拼音，支持自定義特殊詞語

后一頁:asp 當日訪問量,全部訪問量,當前在線人數統計